X86_ASM

寻址方式在结构化数据访问中的应用

• 编程实现：将datasg段中的数据按如下格式写入到table表中，并计算21年中的人均收入（取整），结果也保存在table表中。

  datasg segment

  db ‘1975’ ‘1976’ ‘1977’ ‘1978’ ‘1979’ ‘1980’ ‘1981’ ‘1982’ ‘1983’

  db ‘1984’ ‘1985’ ‘1986’ ‘1987’ ‘1988’ ‘1989’ ‘1990’ ‘1991’ ‘1992’

  db ‘1993’ ‘1994’ ‘1995’

  ;以上是表示21年的21个字符串

  dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514

  dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000, 5937000

  ;以上是表示21年公司总收的21个dword型数据

  dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226

  dw 11542,14430,45257,17800

  ;以上是表示21年公司雇员人数的21个word型数据

  datasg ends

  table segment

  db 21 dup('year summ ne ?? ')

  table ends

  编程，将data段中的数据按照如下格式写入到table段中，并计算21年中的人均收入（取整），结果也按照下面的格式保存在table段中。

  	年份 （4字节）	空格	收入 （4字节）	空格	雇员数 (2字节)	空格	人均收入 （2字节）	空格
  行内 地址 一年占 1行，每 行的起始地址	0	1	2	3	4	5	6	7	8	9	A	B	C	D	E	F
  table:0	‘1975’		16		3		?
  ……
  table:140H	‘1995’		5937000		17800		?

• 源码：

assume cs:code,ds:data,es:table,ss:stack1

data segment
  db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
  db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
  db '1993','1994','1995'
  ;以上是表示21年的21个字符串

  dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140317,197514
  dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
  ;以上表示21年公司总收入的21个dword型数据

  dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
  dw 11542,14430,15257,17800
  ;以上是表示21年公司雇员人数的21个word型数据
data ends

table segment
  db 21 dup ('year summ ne ?? ')
table ends

stack1 segment para stack
    db 20h dup(0)
stack1 ends

code segment
start:
    mov ax,data
    mov ds,ax

    mov ax,table
    mov es,ax
    ;初始化段寄存器

    mov bx,0  ;bx用于定位数组中具体元素起始地址
    mov bp,0  ;bp用于定位table结构中每个数组元素起始地址
    mov cx,21
   
s:  
    push 0[bx]                      ;找到第一个数组起始地址，按字进行数据传送处理。
    pop es:[bp]
    push 2[bx]
    pop es:[bp].2
    mov byte ptr es:[bp].4,' '  ;传入一个空格
  

    push 84[bx]
    pop es:[bp].5
    push 86[bx]
    pop es:[bp].7
    mov ax,es:[bp].5
    mov dx,es:[bp].7
    ;将被除数传入ax，dx中
    ;传第二列四个字节的收入

    mov byte ptr es:[bp].9,' '  ;传入一个空格

    push ax
    push dx
    mov dx,0
    mov ax,bx
    push bx
    mov bx,2
    div bx
    pop bx
    mov si,ax       ;将bx除以2，每次循环bx加4，但是职员数组每个元素占两个字节
    push 168[si]
    pop es:[bp].0AH
    ;传入两个字节的雇员数
    pop dx
    pop ax

    mov byte ptr es:[bp].0CH,' '
    ;传送一个空格

    push ax
    push dx
    mov dx,0
    mov ax,bx
    push bx
    mov bx,2
    div bx
    mov si,ax       ;将bx除以2，每次循环bx加4，但是职员数组每个元素占两个字节
    
    pop bx
    pop dx
    pop ax
    div word ptr 168[si]
    mov es:[bp].0DH,ax
    ;传送两个字节的人均收入

    mov byte ptr es:[bp].0FH,' '
    ;传送一个空格

    add bp,16
    add bx,4
    loop s
    
    mov ah,4ch
    int 21h
code ends
end start

控制字符串在屏幕上的输出

8086CPU支持80×25彩色字符模式，其显示缓冲区（以下简称为显示缓冲区）的结构如下：

内存地址空间中，B8000H～BFFFFH共32KB的空间，为80×25 彩色字符模式的显示缓冲区。向这个地址空间写入数据，写入的内容将立即出现在显示器上。

在80×25彩色字符模式下，显示器可以显示25行，每行80个字符，每个字符可以有256种属性（背景色、前景色、闪烁、高亮等组合信息）。这样，一个字符在显示缓冲区中就要占两个字节，分别存放字符的ASCII码和属性。80×25模式下，一屏的内容在显示缓冲区中共占4000个字节。显示缓冲区分为8页，每页4KB（≈4000B），显示器可以显示任意一页的内容。一般情况下，显示第0页的内容。也就是说通常情况下，B8000H～B8F9FH中的4000个字节的内容将出现在显示器上。

在一页显示缓冲区中：

偏移000～09F对应显示器上的第1行（80个字符占160个字节）；

偏移0A0～13F对应显示器上的第2行；

偏移140～lDF对应显示器上的第3行；

依此类推，可知，偏移F00～F9F对应显示器上的第25行。

在一行中，一个字符占两个字节的存储空间（一个字），低位字节存储字符的ASCII码，高位字节存储字符的属性。一行共有80个字符，占160个字节。

即在一行中：

00-01单元对应显示器上的第1列：

02-03单元对应显示器上的第2列：

04-05单元对应显示器上的第3列：

依此类推，可知，9E～9F单元对应显示器上的第80列。

可以看出，在显示缓冲区中，偶地址存放字符，奇地址存放字符的颜色属性。一个在屏幕上显示的字符，具有前景（字符色）和背景（底色）两种颜色， 符还可以以高亮度和闪烁的方式显示。前景色、背景色、闪烁、高亮等信息被记录在属性字节中。属性字符的含义如下：

可以按位设置属性字节，从而配出各种不同的前景色和背景色。

比如：

红底绿字，属性字节为：01000010B;

红底闪烁绿字，属性字节为：11000010B;

红底高亮绿字属性字节为：01001010B;

黑底白字，属性字节为：00000111B;

白底蓝字，属性字节为：011l0001B。

• 实现效果图：

  

• 源码

  data segment
      db 'welcome to masm!'
  data ends
  
  code segment
  assume cs:code,ds:data
  start:
      mov dx,data
      mov ds,dx
  
      mov dx,0b800h
      mov es,dx
  
      mov cx,912         ;初始化第一行之前其他空白字符cx循环次数。
      mov di,0
  bk1:
      mov byte ptr es:[di],3
      mov byte ptr es:[di+1],10010100b
      inc di
      inc di
      loop bk1             ;第一次初始化空白字符
  
      mov cx,16
      mov bx,0
  main1:
      mov al,[bx]
      mov es:[di],al
      mov byte ptr es:[di+1],00000010b  
      inc di
      inc di
      inc bx
      loop main1
  
      mov cx,64        ;初始化第二行之前其他空白字符cx循环次数。
  bk2:
      mov byte ptr es:[di],3
      mov byte ptr es:[di+1],10010100b
      inc di
      inc di
      loop bk2             ;第二次初始化空白字符
  
      mov cx,16
      mov bx,0
  main2:
      mov al,[bx]
      mov es:[di],al
      mov byte ptr es:[di+1],00100100b  
      inc di
      inc di
      inc bx
      loop main2
  
      mov cx,64        ;初始化第三行之前其他空白字符cx循环次数。
  bk3:
      mov byte ptr es:[di],3
      mov byte ptr es:[di+1],10010100b
      inc di
      inc di
      loop bk3            ;第二次初始化空白字符
  
      mov cx,16
      mov bx,0
  main3:
      mov al,[bx]
      mov es:[di],al
      mov byte ptr es:[di+1],01110001b  
      inc di
      inc di
      inc bx
      loop main3
  
      mov cx,912        ;初始化其他空白字符cx循环次数。 
  bk4:
      mov byte ptr es:[di],3
      mov byte ptr es:[di+1],10100100b
      inc di
      inc di
      loop bk4     ;初始化其他空白字符
  
      
      mov ax,4c00h
      int 21h
  code ends
  end start

  编写子程序实现显示控制

  编程实现：

  （1）子程序：show_str

  功能：在指定的位置，用指定的颜色，显示一个以0结束的字符串；

  参数：（dh）=行号（取值范围0～24)，(dl）＝列号（取值范围0～79),

  (cl）=颜色，ds:si指向字符串的首地址。

  返回：无

  （2）子程序：dtoc

  功能：将word型数据转变为表示十进制数的字符串，字符串以0为结尾符。参数：（ax）＝word型数据，ds:si指向字符串的首地址。

  返回： 无

  （3）编制程序通过调用上述子程序将数值12345在屏幕的8行3列进行显示。

  实现效果：

  

  

  源码：

  assume ds:data,cs:code
  data segment
      db 10 dup(0)
  data ends
  
  code segment
  start:
      mov ax,data
      mov ds,ax
  
      mov ax,12345
      mov si,0
      call dtoc
  
      mov dh,8
      mov dl,3
      mov cl,2
      call show_str
  
      mov ax,4c00h
      int 21h
  
      
  ;ax传递word型数据
  ;ds:si指向字符串的首地址
  dtoc    PROC
      push dx
      push bx
      push si
      push cx
      mov cx,0
  lp4:   
      mov dx,0
      mov bx,10
      div bx      ;商在ax中，余数在dx中
  
      add dx,30h  ;余数(低位)转化为字符串
      push dx
                      
      inc cx
      cmp ax,0    ;商等于0的说明最后一位
      jnz lp4
  
  lp5:
      pop dx
      mov ds:[si],dx
      inc si
      loop lp5
  
      mov byte ptr ds:[si],0
  
      pop cx
      pop si 
      pop bx 
      pop dx
      ret
  dtoc    endp
  
  ;用dh传递行数，0-24；dl传递列数0-79
  ;cl传递字颜色形式，ds:si指向字符串首地址。show_str PROC
  show_str PROC
      push ax
      push es
      push dx
      push cx
      push di
      push si
      push ds
      push bx
      
      mov ax,0b800H
      mov es,ax       ;显示缓冲区目的段地址
  
      mov al,160
      mul dh          ;前面行数的字节数
      
      add dl,dl       ;列数中跨越的字节数
  
      mov dh,0
      add dx,ax
      mov di,dx      ;显示位置偏移量传给di
  
      push di
      mov di,0
  lp1:
      cmp di,dx
      jz exit1
      mov byte ptr es:[di],0
      mov byte ptr es:[di+1],00100000b
      inc di
      inc di
      jmp lp1
  exit1:
      pop di
  lp2:
      cmp byte ptr ds:[si],0
      jz  exit2
                              ;字符不为空
      mov al,ds:[si]          ;进行字符填充
      mov es:[di],al
      mov byte ptr es:[di+1],cl
      inc di
      inc di
      inc si
      jmp lp2
  exit2:
  lp3:
          cmp di,4000
          jz exit3
  
          mov byte ptr es:[di],0
          mov byte ptr es:[di+1],00100000b
          inc di
          inc di
          jmp lp3
  exit3:
  
      pop bx
      pop ds
      pop si
      pop di
      pop cx
      pop dx
      pop es
      pop ax
      ret
  show_str endp
  
  code ends
  end start

  编写子程序实现字符串转换

  编写一个子程序，将包含任意字符，以0结尾的字符串中的小写字母转变为大写字母。

  assume cs:codesg
    datasg segment
    db "Beginner's All-purpose Symbolic Instruction Code.",0
    datasg ends
    codesg segment
    begin:
    mov ax,datasg
    mov ds,ax
    mov si,0
    call letterc
    mov ax,4c00h
    int 21h
    letterc: ;子程序部分[开始]
    ret  ;子程序部分[结束]
    codesg ends
    end begin

  实现效果：

  

  源码：

  assume ds:data,cs:code
  data segment
      db "Beginner's All-purpose Symbolic Instruction Code.",0
  data ends
  
  code segment
  start:
      mov ax,data
      mov ds,ax
      mov si,0
      call letterc
  
      mov dh,13
      mov dl,18
      mov cl,00100100b
      call show_str
  
      mov ax,4c00h
      int 21h
  
  ;ds:si指向字符串首地址。
  letterc PROC
      push ds
      push si
   
  lp4:
      cmp byte ptr ds:[si],0
      jz  exit4
                              ;字符不为空
     cmp byte ptr ds:[si],'a'
     jb lp5
  
     cmp byte ptr ds:[si],'z'
     ja lp5
  
     and byte ptr ds:[si],11011111b
  lp5:
     inc si
     jmp lp4
  exit4:
  
      pop si
      pop ds
      
      ret
  letterc endp
  
  show_str PROC
      push ax
      push es
      push dx
      push cx
      push di
      push si
      push ds
      push bx
      
      mov ax,0b800H
      mov es,ax       ;显示缓冲区目的段地址
  
      mov al,160
      mul dh          ;前面行数的字节数
      
      add dl,dl       ;列数中跨越的字节数
  
      mov dh,0
      add dx,ax
      mov di,dx      ;显示位置偏移量传给di
  
      push di
      mov di,0
  lp1:
      cmp di,dx
      jz exit1
      mov byte ptr es:[di],0
      mov byte ptr es:[di+1],00100000b
      inc di
      inc di
      jmp lp1
  exit1:
      pop di
  lp2:
      cmp byte ptr ds:[si],0
      jz  exit2
                              ;字符不为空
      mov al,ds:[si]          ;进行字符填充
      mov es:[di],al
      mov byte ptr es:[di+1],cl
      inc di
      inc di
      inc si
      jmp lp2
  exit2:
  lp3:
      cmp di,4000
      jz exit3
  
      mov byte ptr es:[di],0
      mov byte ptr es:[di+1],00100000b
      inc di
      inc di
      jmp lp3
  exit3:
  
      pop bx
      pop ds
      pop si
      pop di
      pop cx
      pop dx
      pop es
      pop ax
      ret
  show_str endp
  
  code ends
  end start